%% Copyright (C) 2013, 2014 Czech Technical University in Prague
%%
%% Authors:
%%     - Karel Kočí
%%
%% Permission is hereby granted, free of charge, to any person
%% obtaining a copy of this software and associated documentation
%% files (the "Software"), to deal in the Software without
%% restriction, including without limitation the rights to use,
%% copy, modify, merge, publish, distribute, sublicense, and/or sell
%% copies of the Software, and to permit persons to whom the
%% Software is furnished to do so, subject to the following
%% conditions:

%% The above copyright notice and this permission notice shall be
%% included in all copies or substantial portions of the Software.

%% THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
%% EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
%% OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
%% NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
%% HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
%% WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
%% FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
%% OTHER DEALINGS IN THE SOFTWARE.
%%
%% File : sfunction_irc.tlc
%% Abstract:
%%     TLC file for inlining RPP IRC input block.
%%
%% References:
%%     BlockTypeSetup() : rtw_tlc.pdf p. 277
%%     Start()          : rtw_tlc.pdf p. 279
%%     Outputs()        : rtw_tlc.pdf p. 281


%implements sfunction_irc "C"

%include "common.tlc"


%% Function: BlockInstanceSetup ================================================
%function BlockInstanceSetup(block, system) void
    %assign irc_num = LibBlockParameterValue(p1, 0)
    
    %switch (%<irc_num>)
        %case 1
            %if EXISTS("rpp_din_10_11_used") == 1
                %<LibBlockReportError(block, "Either IRC1 or Digital Input pin 10 and 11 blocks are allowed in one model, not both.")>
            %else
                %assign ::rpp_irc_1_used = 1
            %endif
            %break
        %case 2
            %if EXISTS("rpp_din_14_15_used") == 1
                %<LibBlockReportError(block, "Either IRC2 or Digital Input pin 14 and 15 blocks are allowed in one model, not both.")>
            %else
                %assign ::rpp_irc_2_used = 1
            %endif
            %break
    %endswitch
%endfunction

%% Function: BlockTypeSetup ====================================================
%function BlockTypeSetup(block, system) void

    %% Ensure required header files are included
    %<RppCommonBlockTypeSetup(block, system)>
    %<LibAddToCommonIncludes("rpp/rpp.h")>
    %assign ::rpp_irc_present=1

%endfunction


%% Function: Start =============================================================
%function Start(block, system) Output

    %if !SLibCodeGenForSim()
        %assign irc_num = LibBlockParameterValue(p1, 0)
        rpp_irc_enable(%<irc_num>);
    %endif

%endfunction


%% Function: Outputs ===========================================================
%function Outputs(block, system) Output

    %if !SLibCodeGenForSim()

        %% Error flag
        %assign err_flag = LibBlockOutputSignal(1, "", "", 0)

        %% Get irc number
        %assign irc_num = LibBlockParameterValue(p1, 0)

        %% Control if irc running
        if (rpp_irc_status(%<irc_num>) != 1) {
            %<err_flag> = TRUE;
        } else {
            %% Return input
            %assign irc_val = LibBlockOutputSignal(0, "", "", 0)
            %<irc_val> = rpp_irc_get(%<irc_num>);
        }

    %endif

%endfunction

%% [EOF]