/***********************************************************************/
/*                                                                     */
/*  ROM.ld:  Linker Script File                                        */
/*                                                                     */
/***********************************************************************/
ENTRY(_startup)

INCLUDE "lpc2103.ld-cfg"

STARTUP(startup.o) 

PROVIDE (_setup_board = 0);

/* Section Definitions */
SECTIONS
{

  /* first section is .text which is used for code */
  .text :
  {
    . = ALIGN(4);
    *(.ivt)
    *(.text)                   /* remaining code */
    *(.rodata)                 /* read-only data (constants) */
    *(.rodata*)
    *(.glue_7)
    *(.glue_7t)
    _etext = ALIGN( 4 ) ;
  } > FLASH

  /* .data section which is used for initialized data */
/*  .data : AT (_etext)
*/
  .data :
          AT ( ADDR( .text ) + SIZEOF( .text ) )
  {
    . = ALIGN(4);
    _data = .;
    *(.data)
    _edata = ALIGN( 4 ) ;
  } > RAM
 
  /* .bss section which is used for uninitialized data */
  .bss (NOLOAD) :
  {
    . = ALIGN(4);
    __bss_start = . ;
    __bss_start__ = . ;
    *(.bss)
    *(COMMON)
    __bss_end__ = ALIGN( 4 ) ;
    end = ALIGN( 4 ) ;
    _end = ALIGN( 4 ) ;
  } > RAM

  .stack :
  {
    _stack = .;
  } > STACK


  /* Stabs debugging sections.  */
  .stab          0 : { *(.stab) }
  .stabstr       0 : { *(.stabstr) }
  .stab.excl     0 : { *(.stab.excl) }
  .stab.exclstr  0 : { *(.stab.exclstr) }
  .stab.index    0 : { *(.stab.index) }
  .stab.indexstr 0 : { *(.stab.indexstr) }
  .comment       0 : { *(.comment) }
  /* DWARF debug sections.
     Symbols in the DWARF debugging sections are relative to the beginning
     of the section so we begin them at 0.  */
  /* DWARF 1 */
  .debug          0 : { *(.debug) }
  .line           0 : { *(.line) }
  /* GNU DWARF 1 extensions */
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_sfnames  0 : { *(.debug_sfnames) }
  /* DWARF 1.1 and DWARF 2 */
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }
  /* DWARF 2 */
  .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  .debug_abbrev   0 : { *(.debug_abbrev) }
  .debug_line     0 : { *(.debug_line) }
  .debug_frame    0 : { *(.debug_frame) }
  .debug_str      0 : { *(.debug_str) }
  .debug_loc      0 : { *(.debug_loc) }
  .debug_macinfo  0 : { *(.debug_macinfo) }
  /* SGI/MIPS DWARF 2 extensions */
  .debug_weaknames 0 : { *(.debug_weaknames) }
  .debug_funcnames 0 : { *(.debug_funcnames) }
  .debug_typenames 0 : { *(.debug_typenames) }
  .debug_varnames  0 : { *(.debug_varnames) }
}