embedded/board/arm/ul_usb1/libs/ldscripts/lpc2103.ld-flash

   1 /***********************************************************************/
   2 /*                                                                     */
   3 /*  ROM.ld:  Linker Script File                                        */
   4 /*                                                                     */
   5 /***********************************************************************/
   6 ENTRY(_startup)
   7
   8 INCLUDE "lpc2103.ld-cfg"
   9
  10 STARTUP(startup.o)
  11
  12 PROVIDE (_setup_board = 0);
  13
  14 /* Section Definitions */
  15 SECTIONS
  16 {
  17
  18   /* first section is .text which is used for code */
  19   .text :
  20   {
  21     . = ALIGN(4);
  22     *(.ivt)
  23     *(.text)                   /* remaining code */
  24     *(.rodata)                 /* read-only data (constants) */
  25     *(.rodata*)
  26     *(.glue_7)
  27     *(.glue_7t)
  28     _etext = ALIGN( 4 ) ;
  29   } > FLASH
  30
  31   /* .data section which is used for initialized data */
  32 /*  .data : AT (_etext)\r*/
  33   .data :
  34           AT ( ADDR( .text ) + SIZEOF( .text ) )
  35   {
  36     . = ALIGN(4);
  37     _data = .;
  38     *(.data)
  39     _edata = ALIGN( 4 ) ;
  40   } > RAM
  41
  42   /* .bss section which is used for uninitialized data */
  43   .bss (NOLOAD) :
  44   {
  45     . = ALIGN(4);
  46     __bss_start = . ;
  47     __bss_start__ = . ;
  48     *(.bss)
  49     *(COMMON)
  50     __bss_end__ = ALIGN( 4 ) ;
  51     end = ALIGN( 4 ) ;
  52     _end = ALIGN( 4 ) ;
  53   } > RAM
  54
  55   .stack :
  56   {
  57     _stack = .;
  58   } > STACK
  59
  60
  61   /* Stabs debugging sections.  */
  62   .stab          0 : { *(.stab) }
  63   .stabstr       0 : { *(.stabstr) }
  64   .stab.excl     0 : { *(.stab.excl) }
  65   .stab.exclstr  0 : { *(.stab.exclstr) }
  66   .stab.index    0 : { *(.stab.index) }
  67   .stab.indexstr 0 : { *(.stab.indexstr) }
  68   .comment       0 : { *(.comment) }
  69   /* DWARF debug sections.
  70      Symbols in the DWARF debugging sections are relative to the beginning
  71      of the section so we begin them at 0.  */
  72   /* DWARF 1 */
  73   .debug          0 : { *(.debug) }
  74   .line           0 : { *(.line) }
  75   /* GNU DWARF 1 extensions */
  76   .debug_srcinfo  0 : { *(.debug_srcinfo) }
  77   .debug_sfnames  0 : { *(.debug_sfnames) }
  78   /* DWARF 1.1 and DWARF 2 */
  79   .debug_aranges  0 : { *(.debug_aranges) }
  80   .debug_pubnames 0 : { *(.debug_pubnames) }
  81   /* DWARF 2 */
  82   .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  83   .debug_abbrev   0 : { *(.debug_abbrev) }
  84   .debug_line     0 : { *(.debug_line) }
  85   .debug_frame    0 : { *(.debug_frame) }
  86   .debug_str      0 : { *(.debug_str) }
  87   .debug_loc      0 : { *(.debug_loc) }
  88   .debug_macinfo  0 : { *(.debug_macinfo) }
  89   /* SGI/MIPS DWARF 2 extensions */
  90   .debug_weaknames 0 : { *(.debug_weaknames) }
  91   .debug_funcnames 0 : { *(.debug_funcnames) }
  92   .debug_typenames 0 : { *(.debug_typenames) }
  93   .debug_varnames  0 : { *(.debug_varnames) }
  94 }