embedded/board/arm/ul_usb1/libs/ldscripts/lpc2148.ld-boot

   1 /***********************************************************************/
   2 /*                                                                     */
   3 /*  ROM.ld:  Linker Script File                                        */
   4 /*                                                                     */
   5 /***********************************************************************/
   6 ENTRY(_startup)
   7
   8 INCLUDE "lpc2148.ld-cfg"
   9
  10 STARTUP(startup.o)
  11
  12 PROVIDE (_setup_board = 0);
  13
  14 /* Section Definitions */
  15 SECTIONS
  16 {
  17
  18   /* first section is .text which is used for code */
  19   .ivt :
  20   {
  21     . = ALIGN(4);
  22     KEEP( *(.ivt) )
  23   } > FLASHBOOT
  24
  25   .text :
  26   {
  27     . = ALIGN(4);
  28     *(.text .stub .text.* .gnu.linkonce.t.*)    /* code */
  29     *(.rodata .rodata.* .gnu.linkonce.r.*)      /* read-only data */
  30     *(.rodata*)
  31     *(.glue_7t)
  32     *(.glue_7)
  33     *(.vfp11_veneer)
  34     *(.v4_bx)
  35     . = ALIGN( 4 ) ;
  36     _etext = . ;
  37   } > FLASHBOOT
  38
  39   .app :
  40   {
  41     PROVIDE (_mem_app_start = . );
  42   } > FLASHAPP
  43
  44   .keyval :
  45   {
  46     PROVIDE (_keyval_start = .);
  47     PROVIDE (_keyval_page_len = KEYVAL_PAGE_LEN );
  48   }> KEYVAL
  49
  50   /* .data section which is used for initialized data */
  51 /*  .data : AT (_etext)\r*/
  52   .data :
  53           AT ( ADDR( .text ) + SIZEOF( .text ) )
  54   {
  55     . = ALIGN(4);
  56     _data = .;
  57     *(.data .data.* .gnu.linkonce.d.*)
  58     . = ALIGN( 4 ) ;
  59     _edata = . ;
  60   } > RAM
  61
  62   /* .bss section which is used for uninitialized data */
  63   .bss (NOLOAD) :
  64   {
  65     . = ALIGN(4);
  66     __bss_start = . ;
  67     __bss_start__ = . ;
  68     *(.bss .bss.*)
  69     *(COMMON)
  70     . = ALIGN( 4 ) ;
  71     __bss_end__ = . ;
  72     end = . ;
  73     _end = . ;
  74   } > RAM
  75
  76   .stack :
  77   {
  78     _stack = .;
  79   } > STACK
  80
  81   /* Stabs debugging sections.  */
  82   .stab          0 : { *(.stab) }
  83   .stabstr       0 : { *(.stabstr) }
  84   .stab.excl     0 : { *(.stab.excl) }
  85   .stab.exclstr  0 : { *(.stab.exclstr) }
  86   .stab.index    0 : { *(.stab.index) }
  87   .stab.indexstr 0 : { *(.stab.indexstr) }
  88   .comment       0 : { *(.comment) }
  89   /* DWARF debug sections.
  90      Symbols in the DWARF debugging sections are relative to the beginning
  91      of the section so we begin them at 0.  */
  92   /* DWARF 1 */
  93   .debug          0 : { *(.debug) }
  94   .line           0 : { *(.line) }
  95   /* GNU DWARF 1 extensions */
  96   .debug_srcinfo  0 : { *(.debug_srcinfo) }
  97   .debug_sfnames  0 : { *(.debug_sfnames) }
  98   /* DWARF 1.1 and DWARF 2 */
  99   .debug_aranges  0 : { *(.debug_aranges) }
 100   .debug_pubnames 0 : { *(.debug_pubnames) }
 101   /* DWARF 2 */
 102   .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
 103   .debug_abbrev   0 : { *(.debug_abbrev) }
 104   .debug_line     0 : { *(.debug_line) }
 105   .debug_frame    0 : { *(.debug_frame) }
 106   .debug_str      0 : { *(.debug_str) }
 107   .debug_loc      0 : { *(.debug_loc) }
 108   .debug_macinfo  0 : { *(.debug_macinfo) }
 109   /* SGI/MIPS DWARF 2 extensions */
 110   .debug_weaknames 0 : { *(.debug_weaknames) }
 111   .debug_funcnames 0 : { *(.debug_funcnames) }
 112   .debug_typenames 0 : { *(.debug_typenames) }
 113   .debug_varnames  0 : { *(.debug_varnames) }
 114 }